Including a date in [[double brackets]] after a MD hyperlink paste

I posted this to the Obsidian forum, but it is more appropriate here. Full disclosure, I know enough about scripts to locate familiar text (e.g. a date format) and edit it with trial and error. No coding experience.

My intent:

I want to copy a markdown link for a specific email. When I paste that link, I want it to come with the date of the email, but in double brackets (e.g. [[Example]]). This is important for Obsidian to create an internal link. If it is surrounding a YYYY-MM-DD format, it will link the paste to something in Obsidian called a Daily Note. Therefore, when I reference a previous daily note, I will see the links to the challenging emails I was working on that day.

What I tried:

I changed the Hookmark script for Mac Mail to put double brackets around the date of the email that is included in the text portion (i.e. not the web address portion) of the markdown hyperlink. As you could anticipate, having double brackets around a date in the bracket portion of the hyperlink causes issues. I also tried to use quotes and escape the characters.

What I think could be the solution, but don’t know how to do it:

There is somewhere else in Hookmark that can append the date in double brackets after the mark down hyperlink on the clipboard. So when I paste it, the normal mark down hyperlink is displayed and the obsidian internal link is after it. I would have no idea how to code this though.

Thanks for any help! MM

Do you mean you would like the markdown link looks like this? If not, could you please post an example here?

[Your iCloud storage is full. [[2023-07-11]] From noreply@email.apple.com to tetatnt@gmail.com](hook://email/234876.93349984.5168599455124%40email.apple.com)

Thank you

1 Like

Yes ideally the inner double brackets, around the date, wouldn’t disrupt the regular markdown syntax for the link when rendered as hypertext in Obsidian.

[Your iCloud storage is full. [[2023-07-11]] From noreply@email.apple.com to tetatnt@gmail.com](hook://email/234876.93349984.5168599455124%40email.apple.com)

As an alternative, how would I append the date after the markdown link copy. Where in Hookmark is it possible to make that change in the script.

[Your iCloud storage is full. From noreply@email.apple.com to tetatnt@gmail.com](hook://email/234876.93349984.5168599455124%40email.apple.com) [[2023-07-11]] 

Thanks for any help. Little to no coding experience.

Here is the script you can try. Please go to Hookmark Preferences window ->Scripts->Mail->Get Address, replace the script with the following script. If anything goes wrong, you can always click on “Reset to default” button to reset the script.

Thank you

Script
-- set longFormName to false to exclude source, destination and date from the names of links to email
global longFormName
global placeMetaDataBeforeSubject
set longFormName to true
set placeMetaDataBeforeSubject to false

-- you may replace these labels if you like, such as "de" and "à" respectively in French
global sourceLabel
global destinationLabel
set sourceLabel to "From"
set destinationLabel to "to"

tell application "Mail"
	
	set frontWinIsMessageViewer to false
	
	set fid to id of front window
	repeat with v in message viewers
		set wid to id of window of v
		if fid = wid then
			set frontWinIsMessageViewer to true
		end if
	end repeat
	
	if frontWinIsMessageViewer then
		try
			set theSelection to selection
			set theMessage to item 1 of theSelection
			set mid to message id of theMessage
			set mid to my encodeText(mid, true, false)
			set sub to subject of theMessage
			set mTitle to my getMessageTitle(sub, theMessage)
			return "[" & mTitle & "](" & "email://" & mid & ")"
		on error eStr number enum
			display dialog eStr & "step 1"
			return
		end try
	end if
	
	try
		set theSelection to selection
		set theMessage to item 1 of theSelection
		set mid to message id of theMessage
		set mid to my encodeText(mid, true, false)
		
		set subj to subject of theMessage
		set wname to name of front window
		
		set astid to AppleScript's text item delimiters
		set AppleScript's text item delimiters to {" ", ": "} -- to strip "re: ", "re:", "Re: ", "fwd:", etc
		repeat with i from 1 to count of text items of subj
			repeat with j from 1 to count of text items of wname
				if text item i of subj is equal to text item j of wname then
					repeat with k from j to (count of text items of subj) - i
						set window_title to text item k of wname
						set subj_name to text item (i + k - j) of subj
						if window_title is not equal to subj_name then
							set AppleScript's text item delimiters to astid
							return
						end if
					end repeat
					set AppleScript's text item delimiters to astid
					set mTitle to my getMessageTitle(subj, theMessage)
					
					return "[" & mTitle & "](" & "email://" & mid & ")" -- an old message
				end if
			end repeat
		end repeat
		set AppleScript's text item delimiters to astid
		
	on error eStr number enum
		display dialog eStr & "step 2"
		
	end try
	
	try
		set searchText to name of front window
		set astid to AppleScript's text item delimiters
		set AppleScript's text item delimiters to {" — "} -- to strip " — mailbox"
		set searchText to text item 1 of searchText
		set AppleScript's text item delimiters to astid
		
		set matchText to paragraphs of (do shell script "mdfind \"kMDItemSubject == " & quoted form of searchText & "\"")
		
		if matchText ≠ {} then
			set targetMatch to (item 1 of matchText) as rich text
			if targetMatch ≠ "false" then
				set lns to paragraphs of (read targetMatch)
				repeat with ln in lns
					if ln starts with "Message-ID:" then
						set x to length of "Message-ID:"
						set ln to characters (x + 1) thru -1 of ln as string
						repeat while ln begins with " "
							set ln to characters (2) thru -1 of ln as string
						end repeat
						repeat while ln begins with "<"
							set ln to characters 2 thru -1 of ln as string
						end repeat
						repeat while ln ends with ">"
							set ln to characters 1 thru -2 of ln as string
						end repeat
						set ln to my encodeText(ln, true, false)
						return "email://" & ln
					end if
				end repeat
			end if
		end if
	on error eStr number enum
		display dialog eStr & "step 3"
		
	end try
end tell
on encodeText(theText, encodeCommonSpecialCharacters, encodeExtendedSpecialCharacters)
	set theStandardCharacters to "abcdefghijklmnopqrstuvwxyz0123456789"
	set theCommonSpecialCharacterList to "$+!'/?;&@=#%><{}\"~`^\\|*"
	set theExtendedSpecialCharacterList to ".-_:"
	set theAcceptableCharacters to theStandardCharacters
	if encodeCommonSpecialCharacters is false then set theAcceptableCharacters to theAcceptableCharacters & theCommonSpecialCharacterList
	if encodeExtendedSpecialCharacters is false then set theAcceptableCharacters to theAcceptableCharacters & theExtendedSpecialCharacterList
	set theEncodedText to ""
	repeat with theCurrentCharacter in theText
		if theCurrentCharacter is in theAcceptableCharacters then
			set theEncodedText to (theEncodedText & theCurrentCharacter)
		else
			set theEncodedText to (theEncodedText & encodeCharacter(theCurrentCharacter)) as string
		end if
	end repeat
	return theEncodedText
end encodeText

on encodeCharacter(theCharacter)
	set theASCIINumber to (the ASCII number theCharacter)
	set theHexList to {"0", "1", "2", "3", "4", "5", "6", "7", "8", "9", "A", "B", "C", "D", "E", "F"}
	set theFirstItem to item ((theASCIINumber div 16) + 1) of theHexList
	set theSecondItem to item ((theASCIINumber mod 16) + 1) of theHexList
	return ("%" & theFirstItem & theSecondItem) as string
end encodeCharacter

on getMessageTitle(subj, theMessage)
	tell application "Mail"
		set subj to subject of theMessage
		if longFormName is false then
			return subj
		end if
		try
			set c to count of to recipients of theMessage
			if c > 0 then
				set toMail to address of item 1 of to recipients of theMessage
			else
				set toMail to ""
			end if
			set fromMail to extract address from sender of theMessage
			
			set d to date received of theMessage
			set mon to month of d as number
			if mon < 10 then
				set mon to "0" & mon
			end if
			set yy to year of d as string
			set dd to day of d as string
			set d to (yy & "-" & mon & "-" & dd)
			if placeMetaDataBeforeSubject then
				set subj to d & " " & sourceLabel & " " & fromMail & " " & destinationLabel & " " & toMail & " " & subj
				
			else
				set subj to subj & " [[" & d & "]] " & sourceLabel & " " & fromMail & " " & destinationLabel & " " & toMail
			end if
			
			
		end try
		return subj
	end tell
end getMessageTitle